/batch
/filename, thole-HB

! start in the preprocessor 
/prep7

! tube is 182mm long, 116mm from actuator end to the hole,
!  tube is 63.5mm in diameter

! loading variables
VBEND=0
HBEND=1
TORQ=0
BNT=0

! Forces
!  if FBEND=250, s_nom=43.5 MPa
!  if FBEND=1000, s_nom=10.86 MPa
!  if FBEND=2301, s_nom=100.0 MPa
!
!  if FTORQ=250, t_nom=1.48 MPa
!  if FTORQ=1000, t_nom=5.95 MPa
!  if FTORQ=16815, t_nom=100.0 MPa
FBEND=1000.0
FTORQ=1000.0

! define some size parameters
DIV_LEN=30  ! divisions along the tube length
DIV_HOLE=30 ! divisions along each 180 degree arc of the hole
DIV_OD=20   ! divisions along each 180 arc of the tube OD

! input the IGES file
/AUX15  
IOPTN,IGES,0
IOPTN,MERG,1
IOPTN,SOLID,0   
IOPTN,GTOLER, DEFA  
IGESIN,tube1,igs,
finish

! return to prep7 and glue areas; creates 1 and 10
/prep7
aglue,10,11

! now segment the lines around the hole
lesize,12,,,DIV_HOLE
lesize,14,,,DIV_HOLE

! segment the lines along the tube length
lesize,10,,,DIV_LEN
lesize,40,,,DIV_LEN

! segment the OD arcs
lesize,5,,,DIV_OD
lesize,8,,,DIV_OD
lesize,39,,,DIV_OD
lesize,22,,,DIV_OD
! Specify the material properties
uimp,1,ex, , ,206e9,
uimp,1,nuxy, , ,0.3,
uimp,1,emis, , ,1,
mat,1

! select the quad element and mesh everything
r,1,.004,0.,0.,0.,0., 
et,1,shell93

TYPE,  1 $ REAL,     1 $ MAT,     1

! areas 10 and 11 define the shell; mesh 'em
amesh,1
smrtsize,,,0.9,1.1
amesh,10

! enter the solver, apply contraints and loads
/solu

! select the PCG solver
eqslv,pcg
*if,VBEND,EQ,1,then
	! apply bending boundary conditions---force
	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,x,0.0317499,0.03176
	f,all,fy,FBEND

	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,x,-0.03176,-0.0317499
	f,all,fy,FBEND

	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,y,0.0317499,0.03176
	f,all,fy,FBEND
	
	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,y,-0.03176,-0.0317499
	f,all,fy,FBEND

	! apply bending boundary conditions---restraint
	allsel
        nsel,r,loc,z,-0.00001,0.01
	d,all,all
*endif

*if,HBEND,EQ,1,then
	! apply bending boundary conditions---force
	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,x,0.0317499,0.03176
	f,all,fx,FBEND

	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,x,-0.03176,-0.0317499
	f,all,fx,FBEND

	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,y,0.0317499,0.03176
	f,all,fx,FBEND
	
	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,y,-0.03176,-0.0317499
	f,all,fx,FBEND

	! apply bending boundary conditions---restraint
	allsel
        nsel,r,loc,z,-0.00001,0.01
	d,all,all
*endif

*if,TORQ,EQ,1,then
	! apply shear boundary conditions---force
	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,x,0.0317499,0.03176
	f,all,fy,-FTORQ

	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,x,-0.03176,-0.0317499
	f,all,fy,FTORQ

	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,y,0.0317499,0.03176
	f,all,fx,FTORQ
	
	allsel	
	nsel,r,loc,z,-0.182,-0.181999
	nsel,r,loc,y,-0.03176,-0.0317499
	f,all,fx,-FTORQ

	! apply bending boundary conditions---restraint
	allsel
        nsel,r,loc,z,-0.00001,0.01
	d,all,all
*endif

*if,BNT,EQ,1,then
	! apply shear boundary conditions---force
	allsel	
	nsel,r,loc,z,-0.16,-0.14999
	nsel,r,loc,x,0.03062,0.03063
	f,all,fy,-21421.3

	allsel	
	nsel,r,loc,z,-0.16,-0.14999
	nsel,r,loc,x,-0.03063,-0.03062
	f,all,fy,28770.8

	allsel	
	nsel,r,loc,z,-0.16,-0.14999
	nsel,r,loc,y,0.03062,0.03063
	f,all,fx,10755.45
	f,all,fy,3674.75
	
	allsel	
	nsel,r,loc,z,-0.16,-0.14999
	nsel,r,loc,y,-0.03063,-0.03062
	f,all,fx,-10755.45
	f,all,fy,3674.75

	! apply bending boundary conditions---restraint
	allsel
        nsel,r,loc,z,-0.00001,0.01
	d,all,all
*endif

allsel


solve
finish

! Enter post-processor and save everything
/post
save
finish